你再也不需要使用Win32应用编程接口或者VB的Shell函数来启动外部应用程序了。因为你可以使用.net框架中的System.Diagnostics.Process类来进行这个操作，从而进一步简化代码。
虽然.NET使很多事情变得更加复杂，但是启动外部应用程序不在此列。在传统VB程序中，你可以使用Shell函数启动一个应用程序。当你传送一个数据文件名的时候，VB在相应应用程序中打开这个数据文件。你可以使用一个任选的Windowstyle参数控制所启动的应用程序的窗口方式。例如，在VB6中，下面这行代码将启动默认的文本编辑器（通常是记事本）并打开文件"c:\somepath\somefile.txt"：
returnID = Shell("c:\somepath\somefile.txt", vbNormalFocus)
通过Microsoft.VisualBasic.Comaptibility域名空间，在VB.net中仍然能够使用Shell功能，并且它已经被做了一些改动，但在.NET框架中它并不是启动应用程序的最好的方法，因为Shell函数有一些严格的限制条件，其中之一就是只能异步地启动程序；在启动应用程序之后，你自己的程序才继续运行。所以你不能直接使用它来启动一个程序，并且只能等到这个程序退出，你才能返回到你自己的程序中。为了在传统VB中做到这点，你必须求助于Windows API，而这需要对窗口句柄、过程识别号、枚举最高级窗口等有所了解。
使用.NET，就能使这个操作变得很简单。你可以使用System.Diagnostics域名空间中的Process类来启动外部程序。你可以简单的使用共享的Process.Start方法启动一个新的过程，把一个可执行文件名或者可执行应用程序的扩展关联文件名作为参数传输给它。例如，下面的代码启动"c:\somepath\somefile.txt"文件。
System.Diagnostics.Process.Start ("c:\somepath\somefile.txt")
Start方法有一个超载的版本，能返回一个Process对象，所以你可以获得对启动的过程的引用，并可用于多种用途：
Dim myProcess As Process = System.Diagnostics.Process.Start
("c:\somepath\somefile.txt")
MessageBox.Show(myProcess.ProcessName)
初看起来，你看上去好象丧失了控制窗口风格的能力（还记得Shell函数的第二个参数吗？），但是事实情况并非如此。在很多情况下，你不需要明确地设置窗口风格，因为默认情况是在一个带有焦点的正常窗口（ProcessWindowStyle.Normal）中启动过程。但是如果你想使用一个不同的窗口风格时，可以使用超载的Process.Start方法接收一个ProcessStartInfo对象参数而不是一个简单的字符串。为了使用它，首先要创建一个ProcessStartInfo对象，然后设置进程初置值。两个超载方法让你设置一个文件名或者一个文件名和一组命令行参数。并且ProcessStartInfo对象还有一个WindowStyle属性，由System.Diagnostics.Process.WindowStyle枚举的值组成。所以你可以调用Process.Start方法并传送一个ProcessStartInfo对象来控制启动的窗口的风格。
Dim psInfo As New _
System.Diagnostics.ProcessStartInfo _
("c:\somepath\somefile.txt")
psInfo.WindowStyle = _
System.Diagnostics.ProcessWindowStyle.Normal
Dim myProcess As Process = _
System.Diagnostics.Process.Start(psInfo)
由于Process类有一个StartInfo属性，它是一个ProcessStartInfo对象，所以另一种产生相同结果的方法是创建一个Process对象并设置它的StartInfo属性。在预创建的Process对象的时候，你可以仅仅调用它的Start方法，而不需使用Process类的共享Start方法。
Dim myProcess As System.Diagnostics.Process = _
new System.Diagnostics.Process()
myProcess.StartInfo.FileName = _
"c:\somepath\somefile.txt"
myProcess.StartInfo.WindowStyle = _
System.Diagnostics.ProcessWindowStyle.Normal
myProcess.Start
在设计期间设置Process参数
.net框架出厂时已经带有在设计期间封装这些代码的Process组件。你可以在工具栏的Components栏目中找到它。为了使用它，把一个Process组件拖到你的窗体上，然后在属性窗口展开StartInfo属性，如下图（图1）所示设置StartInfo的值。
图1：你可以添加一个Process组件到一个窗体中，让你在设计期间设置属性而不是在运行期间设置属性。
监视启动过程
到目前为止，你看到的启动过程还是使用一种异步的方式；就象传统VB Shell函数一样。换句话说，在启动这个过程之后，父程序中的代码才能继续执行。你需要一些监视被启动的过程的方法，并弄清楚它们什么时候退出或者是否仍在运行。根据你的应用程序的具体情况，你可能需要使用不同的方式来处理这个问题。
启动过程，停止你的程序直到它退出。
启动过程，监视它，并只有当它结束时才做某些事情，同时让你的程序正常地运行。
启动过程，给它一些输入，让它处理这些输入，然后强迫它退出。
启动过程，并且只要启动的过程正在运行或者运行期间没有出现问题，就执行某些操作。如果过程退出或者停止，你需要作出某些动作。
启动过程，并给它一些特殊的输入，并/或取得进一步处理产生的输出结果。例如，你可能想启动一个命令窗口，以编程方式在这个窗口中输入一些内容，然后取得并处理输出结果。
启动一个过程并等到它退出
等待一个启动的过程结束的最简单的方法时调用Process.WaitForExit方法。这导致正在启动的过程停止执行直到启动过的过程退出。然而不幸的是，当你直接从一个Windows窗体中使用这个方法的时候，它还能导致窗体停止对系统事件的响应，比如Paint。
所以一般来说你不会想从一个按钮中使用WaitForExit方法来启动一个外部程序（虽然使用WaitForExit方法非常适于从一个没有可视用户界面的应用程序中启动另一个过程，例如从一个ASP.net应用程序服务器中调用控制台应用程序）。图二中所示的样本窗体有一个名为"Launch and WaitForExit"的按钮，让你在从一个窗体中使用这个方法时能看到会发生什么情况。
图2：样本窗体让你测试并试验各个的启动过程的方法。
Private Sub btnWaitForExit_Click( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles btnWaitForExit.Click
'创建一个新过程
Dim myProcess As Process = _
System.Diagnostics.Process.Start("sample.txt")
' 等待直到它退出
myProcess.WaitForExit()
' 显示结果
MessageBox.Show("Notepad was closed at: " & _
myProcess.ExitTime & "." & _
System.Environment.NewLine & "Exit Code: " & _
myProcess.ExitCode)
myProcess.Close()
End Sub
前面的例子说明一个有趣的情况。即使启动的过程结束后，你仍然有访问代码中的Process对象的能力；然而这种情况下，大多数Process属性是不可用的，因为过程本身不再存在。你仍然可以读取ExitCode和ExitTime属性，这两个属性分别返回整数和日期时间型的值。DOS命令设置了一个退出码，让你知道是否出现错误。.NET和其他的Windows应用程序可以通过使用main方法的返回值设置这个值。默认情况下，这个值等于零。对于DOS命令，一个非零ExitCode值要么表明出现一个错误，要么表明命令过程被异常中止。
启动不可视的过程
在一个可见的窗口中，你不必启动一个过程；有时你仅仅想运行一个过程并取得输出值。下面的例子把当前的目录转换为系统目录，然后运行一个DOS的dir命令，这个命令带有"* .com"参数，列出目录中所有带有.com扩展名的文件。在Windows XP中，命令shell解释器把"&&"运算符认做一个命令分隔符，所以你可以在一行中放置多个命令。">>"运算符把输出值重定向到一个制定文件中。在这种情况下，代码把dia显示的结果导入Application.StartupPath属性指定的路径中的"dirOutput.txt"文件。
Dim myProcess As Process = New Process()
Dim s As String
Dim outfile As String = Application.StartupPath & _
"\dirOutput.txt"
'取得系统路径
Dim sysFolder As String = _
System.Environment.GetFoldERPath _
(Environment.SpecialFolder.System)
'设置文件名和命令行参数
myProcess.StartInfo.FileName = "cmd.exe"
myProcess.StartInfo.Arguments = "/C cd " & _
sysFolder & " && dir *.com >> " & Chr(34) & _
outfile & Chr(34) & " && exit"
'在一个隐藏窗口中启动过程
myProcess.StartInfo.WindowStyle = _
ProcessWindowStyle.Hidden
myProcess.StartInfo.CreateNoWindow = True
myProcess.Start()
'如果过程在1秒中不能完成，那么销毁它
myProcess.WaitForExit(1000)
If Not myProcess.HasExited Then
myProcess.Kill()
End If
'显示退出时间和退出码
MessageBox.Show("The 'dir' command window was " & _]
"closed at: " & myProcess.ExitTime & "." & _
System.Environment.NewLine & "Exit Code: " & _
myProcess.ExitCode)
myProcess.Close()
前面的代码返回一个零（0）值的ExitCode。如果想看看非零值ExitCode的例子，可以在系统目录上附加一个"X"或其他字符，这样能使它非法。这导致出现一个错误，ExitCode值将不同。因为一个带有错误的过程可能会一直运行下去，代码在返回到控制启动的程序之前，使用一个超载WaitForExit方法来等待几毫秒时间。上面的代码等待一秒钟，然后调用Kill方法结束启动的过程，强迫过程退出。请查看一下你的应用程序启动目录中的dirOutput.txt是否存在。
探测一个过程什么时候退出
在VB6中，你可以调用Win32 API的GetModuleUsage()函数来判定过程什么时候结束。在.net中，相应的操作是在启动过程后不断的循环，检查Process.HasExited属性，并且调用Application.DoEvents方法处理你的应用程序中其他的事件，直到过程结束。
Do While Not myProcess.HasExited
Application.DoEvents
Loop
但是Process类给了你一个更简洁的方法来判断过程什么时候退出--它可以产生一个Exited事件。为了使这种情况出现，你需要设置Process.EnableRaisingEvents属性为True（默认情况下属性值为False），并创建一个事件句柄。例如：
'允许过程产生事件
myProcess.EnableRaisingEvents = True
'添加一个Exited事件句柄
AddHandler myProcess.Exited, _
AddressOf Me.ProcessExited
'开始过程
myProcess.Start()
'事件处理程序
Friend Sub ProcessExited(ByVal sender As Object, _
ByVal e As System.EventArgs)
Dim myProcess As Process = DirectCast( _
sender, Process)
MessageBox.Show("The process exited, raising " & _
"the Exited event at: " & myProcess.ExitTime & _
"." & System.Environment.NewLine & _
"Exit Code: " & myProcess.ExitCode)
myProcess.Close()
End Sub
使用这两种方法潜在的问题就是如果启动的过程挂起或者从不退出，你的应用程序就会一直停止。解决办法就是添加一个定时器，周期性的检查启动的程序是否有响应。
控制过程输入输出
有时候，你可能不仅仅想使用简单的命令行，而是想把更复杂的输入信息直接发送到启动的过程中。前面例子中的把输出导入到文件中的方法，并不总是最好的选择。在许多情况下，把输出直接导回你的应用程序可能更有效。对于使用StdIn、StdOut和StdErr的程序，比如控制台应用程序，你可以覆盖默认方法，提供一个StreamWriter来输入，并提供一个StreamReaders来读取StdOut和StdErr输出值。当你启动过程的时候，你需要设置ProcessStartInfo对象的RedirectStandardInput、RedirectStandardOutput和RedirectStandardError属性为True。然后，在启动过程之后，使用Process对象的StandardInput、StandardOutput和StandardError属性来把输入输出流分配到StreamReader和StreamWriter对象。
警告：默认情况下，框架使用Win32 ShellExecute函数，在内部启动过程；但是当你想再分配输入输出流的时候，你必须在启动过程之前设置ProcessStartInfo.UseShellExecute属性为False。注意当你那么做的时候，你必须要么指定到文件的完全路径，要么文件位置必须在环境路径中。例如，下面的代码创建一个不可见的窗口，取得系统目录中.com文件的目录列表，然后在一个消息框中显示结果。
Dim myProcess As Process = New Process()
Dim s As String
myProcess.StartInfo.FileName = "cmd.exe"
myProcess.StartInfo.UseShellExecute = False
myProcess.StartInfo.CreateNoWindow = True
myProcess.StartInfo.RedirectStandardInput = True
myProcess.StartInfo.RedirectStandardOutput = True
myProcess.StartInfo.RedirectStandardError = True
myProcess.Start()
Dim sIn As StreamWriter = myProcess.StandardInput
sIn.AutoFlush = True
Dim sOut As StreamReader = myProcess.StandardOutput
Dim sErr As StreamReader = myProcess.StandardError
sIn.Write("dir c:\Windows\system32\*.com" & _
System.Environment.NewLine)
sIn.Write("exit" & System.Environment.NewLine)
s = sOut.ReadToEnd()
If Not myProcess.HasExited Then
myProcess.Kill()
End If
MessageBox.Show("The 'dir' command window was " & _
closed at: " & myProcess.ExitTime & "." & _
System.Environment.NewLine & "Exit Code: " & _
myProcess.ExitCode)
sIn.Close()
sOut.Close()
sErr.Close()
myProcess.Close()
MessageBox.Show(s)
对于不使用StdIn的程序，你可以使用SendKeys方法来输入按键事件。例如，下面这些代码启动记事本并输入一些文本。
Dim myProcess As Process = New Process()
myProcess.StartInfo.FileName = "notepad"
myProcess.StartInfo.WindowStyle = _
ProcessWindowStyle.Normal
myProcess.EnableRaisingEvents = True
AddHandler myProcess.Exited, _
AddressOf Me.SendKeysTestExited
myProcess.Start()
myProcess.WaitForInputIdle(1000)
If myProcess.Responding Then
System.Windows.Forms.SendKeys.SendWait( _
"This text was entered using the " & _
"System.Windows.Forms.SendKeys method.")
Else
myProcess.Kill()
End If
你可以使用SendKeys方法发送任何键入值，包括Alt、Ctrl和Shift键；所以，你可以使用它来保存或载入文件、退出或者执行其他菜单驱动的命令。然而、SendKeys方法只发送键入值到活动窗口（就是有焦点的那个窗口），所以如果一个应用程序在这个过程中失去焦点，那么可能会出现问题。
