分享
 
 
 

复制表结构的通用存储过程

王朝other·作者佚名  2006-01-31
窄屏简体版  字體: |||超大  

复制表结构的通用存储过程

-- Transfer对象的重要属性

-- 1. 属性

属性名 类型 描述

--------------------------------- ------------------- --------------------

CopyAllDefaults Boolean 所有默认值

CopyAllObjects Boolean 所有对象

CopyAllRules Boolean 所有规则

CopyAllStoredProcedures Boolean 所有存储过程

CopyAllTables Boolean 所有表

CopyAllTriggers Boolean 所有触发器

CopyAllUserDefinedDatatypes Boolean 所有用户自定义类型

CopyAllViews Boolean 所有视图

CopyData Boolean 所有数据

DestDatabase String 目标对象数据库

DestLogin String 目标数据库登陆用户名

DestPassword String 目标数据库登陆密码

DestServer String 目标服务器

DestUseTrustedConnection Boolean 用户信任连接

DropDestObjectsFirst Boolean 是否先删除目标对象

IncludeDependencies Boolean 是否包含依靠对象

ScriptType Boolean 脚本类型

-- 2. 重要方法:

方法名称 功能描述

--------------------------- --------------------------

AddObject 增加对象

AddObjectByName 通过对象名称增加对象

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[P_CopyDB]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)

drop procedure [dbo].[P_CopyDB]

GO

/*-- 在 SQLServer 中使用SQLDMO.Transfer 实现数据迁移

存储过程实现源数据库到目标数据库的对象和数据的复制

要求源数据库和目标数据库在同一服务器

如果是要实现不同服务器之间的复制,则需要增加验证信息

--邹建 2005.07(引用请保留此信息)--*/

/*--调用示例

CREATE DATABASE test

EXEC P_CopyDB @Source_DB='northwind',@Des_DB='test'

DROP DATABASE test

--*/

CREATE PROCEDURE P_CopyDB

@Des_DB sysname, --目标数据库

@Obj_Type nvarchar(4000)=N'',--复制的对象类型,可以是下列字符串列表:

-- O 所有对象,D 默认值,R 规则,P 存储过程

-- T 表,TR 触发器,DT 用户定义数据类型

-- V 视图,DATA 数据,DEL 删除目标对象

@Source_DB sysname=N'', --源数据库

@ServerName sysname=N'', --服务器名

@UserName sysname=N'', --用户名,不指定则表示使用 Windows 身份登录

@pwd sysname=N'' --密码

AS

SET NOCOUNT ON

DECLARE @srvid int,@Dbid int,@S_dbid int,@D_dbid int,@TransferID int,

@err int,@src varchar(255), @desc varchar(255)

IF ISNULL(@ServerName,N'')=N'' SET @ServerName=@@SERVERNAME

IF ISNULL(@Source_DB,N'')=N'' SET @Source_DB=DB_NAME()

--创建sqldmo对象·

EXEC @err=sp_oacreate 'sqldmo.sqlserver',@srvid OUT

IF @err<>0 GOTO lb_Err

--连接服务器

IF ISNULL(@UserName,N'')=N'' --使用 Windows 身份登录

BEGIN

EXEC @err=sp_oasetproperty @srvid,'loginsecure',-1

IF @err<>0 GOTO lb_Err

EXEC @err=sp_oamethod @srvid,'connect',NULL,@servername

END

ELSE

EXEC @err=sp_oamethod @srvid,'connect',NULL,@servername,@UserName,@pwd

IF @err<>0 GOTO lb_Err

--获取数据库集

EXEC @err=sp_oagetproperty @srvid,'databases',@Dbid OUT

IF @err<>0 GOTO lb_Err

--选择源数据库

EXEC @err=sp_oamethod @Dbid,'item',@S_dbid OUT,@Source_DB

IF @err<>0 GOTO lb_Err

--选择目标数据库

EXEC @err=sp_oamethod @Dbid,'item',@D_dbid OUT,@Des_DB

IF @err<>0 GOTO lb_Err

--设置复制的对象

EXEC @err=sp_oacreate 'SQLDMO.Transfer',@TransferID OUT

IF @err<>0 GOTO lb_Err

--设置目标服务器信息

EXEC @err=sp_oasetproperty @TransferID,'DestServer',@ServerName

IF @err<>0 GOTO lb_Err

--设置连接用户

IF ISNULL(@UserName,N'')=N'' --使用 Windows 身份登录

BEGIN

EXEC @err=sp_oasetproperty @TransferID,'DestUseTrustedConnection',1

IF @err<>0 GOTO lb_Err

END

ELSE

BEGIN

EXEC @err=sp_oasetproperty @TransferID,'DestLogin',@UserName

IF @err<>0 GOTO lb_Err

EXEC @err=sp_oasetproperty @TransferID,'DestPassword',@pwd

IF @err<>0 GOTO lb_Err

END

--设置复制对象信息

EXEC @err=sp_oasetproperty @TransferID,'DestDatabase',@Des_DB

IF @err<>0 GOTO lb_Err

DECLARE tb CURSOR FAST_FORWARD LOCAL

FOR

SELECT Name FROM(

SELECT KeyWord=N',D,', Name=N'CopyAllDefaults' UNION ALL

SELECT KeyWord=N',O,', Name=N'CopyAllObjects' UNION ALL

SELECT KeyWord=N',R,', Name=N'CopyAllRules' UNION ALL

SELECT KeyWord=N',P,', Name=N'CopyAllStoredProcedures' UNION ALL

SELECT KeyWord=N',T,', Name=N'CopyAllTables' UNION ALL

SELECT KeyWord=N',TR,', Name=N'CopyAllTriggers' UNION ALL

SELECT KeyWord=N',DT,', Name=N'CopyAllUserDefinedDatatypes' UNION ALL

SELECT KeyWord=N',V,', Name=N'CopyAllViews' UNION ALL

SELECT KeyWord=N',DATA,',Name=N'CopyData' UNION ALL

SELECT KeyWord=N',DEL,', Name=N'DropDestObjectsFirst'

)A WHERE CHARINDEX(KeyWord,

CASE WHEN ISNULL(@Obj_Type,N'')='' THEN ',O,DATA,' ELSE @Obj_Type END)>0

OPEN tb

FETCH tb INTO @src

WHILE @@FETCH_STATUS=0

BEGIN

EXEC @err=sp_oasetproperty @TransferID,@src,1

IF @err<>0 GOTO lb_Err

FETCH tb INTO @src

END

CLOSE tb

DEALLOCATE tb

--复制对象

EXEC @err=sp_oamethod @S_dbid,'Transfer',null,@TransferID

IF @err<>0 GOTO lb_Err

--结束

SET @err=0

GOTO lb_Exit

--错误处理

lb_Err:

EXEC sp_oageterrorinfo NULL, @src OUT, @desc OUT

RAISERROR(N'错误编号 %#x, 错误源 "%s", 错误描述 "%s"',16,1,@err,@src,@desc)

RETURN -1

lb_Exit:

EXEC sp_OADestroy @Dbid

EXEC sp_OADestroy @srvid

EXEC sp_OADestroy @TransferID

RETURN @err

GO

原帖地址

 
 
 
免责声明:本文为网络用户发布,其观点仅代表作者个人观点,与本站无关,本站仅提供信息存储服务。文中陈述内容未经本站证实,其真实性、完整性、及时性本站不作任何保证或承诺,请读者仅作参考,并请自行核实相关内容。
2023年上半年GDP全球前十五强
 百态   2023-10-24
美众议院议长启动对拜登的弹劾调查
 百态   2023-09-13
上海、济南、武汉等多地出现不明坠落物
 探索   2023-09-06
印度或要将国名改为“巴拉特”
 百态   2023-09-06
男子为女友送行,买票不登机被捕
 百态   2023-08-20
手机地震预警功能怎么开?
 干货   2023-08-06
女子4年卖2套房花700多万做美容:不但没变美脸,面部还出现变形
 百态   2023-08-04
住户一楼被水淹 还冲来8头猪
 百态   2023-07-31
女子体内爬出大量瓜子状活虫
 百态   2023-07-25
地球连续35年收到神秘规律性信号,网友:不要回答!
 探索   2023-07-21
全球镓价格本周大涨27%
 探索   2023-07-09
钱都流向了那些不缺钱的人,苦都留给了能吃苦的人
 探索   2023-07-02
倩女手游刀客魅者强控制(强混乱强眩晕强睡眠)和对应控制抗性的关系
 百态   2020-08-20
美国5月9日最新疫情:美国确诊人数突破131万
 百态   2020-05-09
荷兰政府宣布将集体辞职
 干货   2020-04-30
倩女幽魂手游师徒任务情义春秋猜成语答案逍遥观:鹏程万里
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案神机营:射石饮羽
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案昆仑山:拔刀相助
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案天工阁:鬼斧神工
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案丝路古道:单枪匹马
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案镇郊荒野:与虎谋皮
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案镇郊荒野:李代桃僵
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案镇郊荒野:指鹿为马
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案金陵:小鸟依人
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案金陵:千金买邻
 干货   2019-11-12
 
推荐阅读
 
 
 
>>返回首頁<<
 
靜靜地坐在廢墟上,四周的荒凉一望無際,忽然覺得,淒涼也很美
© 2005- 王朝網路 版權所有