下面是ExcelChart组件中的一些基本函数和事件。
SetChartBaseProps函数
如下面的代码所示，SetChartBaseProps()函数的作用是设置图表基本属性的默认值。
Private Sub SetChartBaseProps()
'--- 为组件用户预定义的属性
With oExcelChart
.ChartType = xl3DColumnClustered
.SizeWithWindow = True
.HasDataTable = False
End With
End Sub
该函数由Class_Intialize事件调用。在这里我们把默认的图表类型设置为三维柱形图。如果SizeWithWindow属性没有设置，则图表的大小会超过Excel工作表的大小，最终也会超过浏览器窗口的大小。Excel图表允许将数值作为一个独立的表格显示，在这里我们通过HasDataTable属性关闭了该功能。
Class_Initialize事件
Class_Initialize()完成一些准备工作。
Private Sub Class_Initialize()
'--- 创建Excel应用实例
Set oExcelApp = CreateObject("Excel.Application")
'---设置Excel应用不可见，然后加入一个工作簿
oExcelApp.Visible = False
oExcelApp.SheetsInNewWorkbook = 1: oExcelApp.Workbooks.Add
With oExcelApp.ActiveWorkbook
'--- 获取第一个工作表
Set oExcelSheet = .Sheets(1)
'--- 加入新的图形工作表
Set oExcelChart = .Sheets.Add(Type:=xlChart)
'--- 设置图表的基本属性
SetChartBaseProps
End With
End Sub
所有基于该类的对象，其初始化过程都会触发这个Class_Initialize事件。第一行代码的作用是初始化一个Excel应用作为ActiveX服务器。用户并不直接访问ActiveX服务器，该服务器仅在内部完成图表绘制工作。Excel应用的visible属性设置成了False，这保证了任何情况下用户都不会直接见到Excel。
默认情况下Excel 2000会将三个空的工作表加入新工作簿。为便于控制，程序把新工作表数量设置成了1，当然必要的时候可以加入新的工作表。接下来程序又将新的工作簿加入到了已经初始化的Excel应用。新加入的工作簿将自动成为活动工作簿，因为它是应用中唯一的工作簿。
第一个工作表也是唯一的工作表，该表可以通过工作簿的Sheets集合访问，程序把它存储到了全局变量oExcelSheet以便其他方法访问。该表实际上用来存储AddDataSeries()函数所传递的数据。接下来程序又将一个新的工作表加入到了Sheets集合，新表的类型为xlChart。第二个工作表用来存放图表，现在我们把它保存到了全局变量oExcelChart。
综上所述，现在组件中有了下面这些对象：
【图2】
Class_Terminate事件
Private Sub Class_Terminate()
If (Not (oExcelApp Is Nothing)) Then
'--- 检查是否确实存在工作簿
If (oExcelApp.Workbooks.Count > 0) Then
'--- 关闭工作簿，忽略任何修改
oExcelApp.Workbooks(1).Close SaveChanges:=False
End If
'--- 退出Excel，释放资源
oExcelApp.Quit: Set oExcelApp = Nothing
End If
End Sub
结束全部工作之后，对象的拆除操作将触发Class_Terminate事件。Class_Terminate检查所有已经分配空间的对象并依次释放它们。工作簿对象包含两个工作表，即图表工作表和数据工作表。在绘制图表之后工作表的内容已经改变，因此，close方法的SaveChanges参数必须指定False以忽略对工作表内容的修改，这样也就避免了每次生成一个图表都要创建一个Excel文件（.xls文件）。程序最后调用Quit方法退出Excel应用并清除对象。
