此文档是Sean Campbell, Scott Swigart, Kris Horrocks, Derek Hatchard, and Peter Bernhardt.等人创作的《向Microsoft Visual Basic程序员介绍Whidbey》一书中的样章，版权归原作者和出版社所有。转载请注明此声明。
本文用通俗的用语和大量的实例向Visual Basic程序员介绍了下一版Visual Basic.Net中将要增加的新功能——泛型。此文章可以帮助广大VB用户了解泛型，以便将来将泛型应用到自己的应用程序中。
应用：泛型
此应用展示了在Visual Basic.Net 中新增加的泛型功能。
新概念
在开始实现泛型以前，有必要花一点时间分析一下为什么要在Visual Basic.Net中增加这一功能。泛型技术源于需要用一种一般的方法处理对象各种可能的类型，而不需要关心他们具体的类型。比如在Visual Basic 6.0中，你能够用一个Collection类储存任何类型的对象。
Visual Basic 6.0 的集合
Visual Basic 6.0 确实允许你将任何东西储存在一个Collection中。但是，Collection类有几个限制。我们用一个例子来说明如何将这个Employee类储存在集合中：
‘ Visual Basic 6.0 代码：类模块Employee
Public SSN As String
Public FirstName As String
Public LastName As String
Public Salary As Currency
将这个类储在集合中的方法显得非常直接。
‘ Visual Basic 6.0 代码
Dim employees As New Collection
Dim emp As Employee
Set emp = New Employee
emp.SSN = "111-11-1111"
emp.FirstName = "Scott"
emp.LastName = "Swigart"
emp.Salary = 50000
employees.Add emp, emp.SSN
这段代码首先创建了一个Collection的实例employees。接着Employee类创建了一个实例，并设置了一些数据。最后，Employee对象被添加到Collection，指定emp.SSN属性作为关键字。下面的代码展示了如何从Collection取出这个Employee对象的实例：
‘ Visual Basic 6.0 代码
Dim emp2 As Employee
Set emp2 = employees("111-11-1111")
现在我们一起来研究一下Visual Basic 6.0的这种集合有什么限制。首先，你的初衷是让employees这个集合只储存Employee类型的对象。但是没有任何机制可以防止将一个别的类型的对象放入这个employees集合，也没有任何东西可以告诉你从这个集合中取出的数据是什么类型。下面的代码照样可以正确编译：
Dim s As String
s = employees("111-11-1111")
虽然开发者可以很明确地知道这不能正确工作，但没有办法让编译器发现这个问题。这样会发生一个运行时错误。集合的使用同样限制了智能感知技术的发挥。看看下面这段代码：
employees("111-11-1111").LastName = "SomeoneElse"
这说明你能直接编辑集合中的项目。但是，IDE的智能感知不能帮助你选择LastName属性。再一次重申，以前的Visual Basic 中集合可以存放任何东西。
使用集合的两个最大的限制是性能和灵活性方面的损失。集合虽然容易使用，但作为一个动态数组使用时性能非常差。集合的设计使它更像是一个字典，所以当你需要的数据结构类似堆栈或队列时，它也不是一个很好的选择。
框架中的集合
.Net框架1.0/1.1通过增加集合的种类解决了一部分问题。新引入System.Collections命名空间以后，你就可以创建更多类型的集合，比如数组表、位数组、哈希表、队列、排序表和堆栈。下表列出了这些类型的用法：
集合名称
用途
ArrayList
数组表能够创建动态增大的数组。
BitArray
位数组是经过优化的，专用于储存布尔值（真/假）的数组。
HashTable
哈希表和Visual Basic 6.0中的Collection类非常相似。它允许你通过关键字找得到对应的值。不过关键字和值 还是任意类型的。
SortedList
排序表和哈希表非常类似，唯一不同的是它的关键字总是排序的。这意味着当你用For …Each语法遍历整个集合时，得到的项目总是经过排序的。
Queue
队列是一种能让被储存的对象先进先出的集合。
Stack
堆栈是一种能让被储存的对象后进先出的集合。
.Net 框架1.0/1.1已经解决了Visual Basic 6.0中的集合在灵活性方面的限制，但是，这些集合仍然是弱类型的，因此你还是可以将任何东西存放到一个ArrayList中，虽然在一个指定的应用中，只有储存唯一的类型才有意义。
你真正想要是指定每个关键字必须都是String而且每个值都是Employee类型。在.Net框架1.0和1.1种，你只有创建自己的类，当然这种方法有些繁琐。如果使用新的.Net框架1.2，这个问题可以用很少的代码来解决，方法就是使用泛型。
深入代码
泛型能够提供严格的类型检查，更好的智能感知功能和更好的性能，就如上一节中介绍的一样。换句话说，他们超越了以前所有集合类所能提供的优点。
感受泛型
接下来你将看到，当你创建一个泛型集合的实例的时候，你需要提供一些信息以便集合类能够被强类型化。这样做有很多优点，包括在编译阶段更多的检查以确保创建更安全和更可靠的代码，更好的智能感知以及更好的性能。有必要提及.Net框架1.2中是在以前版本的基础上新增加泛型集合。.Net框架1.2不会强迫你使用泛型。
如果你想使用泛型类型，首先需要包含System.Collections.Generic这个命名空间。这允许访问带有泛型功能的Dictionary、List、Queue、SortedDictionary和Stack类。下面btnConsumeGenerics_Click事件中的代码提供了一个使用泛型字典的例子：
‘ Visual Basic .NET 8.0 代码
Private Sub btnConsumeGenerics_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnConsumeGenerics.Click
Dim employees As New Dictionary(Of String, Employee)
Dim emp As Employee
emp = New Employee
emp.SSN = "111-11-1111"
emp.FirstName = "Scott"
emp.LastName = "Swigart"
emp.Salary = 50000
employees.Add(emp.SSN, emp)
Dim emp2 As Employee
emp2 = employees.Item("111-11-1111")
Dim s As String
's = employees.Item("111-11-1111") ' This is now a syntax error
employees.Item("111-11-1111").LastName = "SomeoneElse"
End Sub
深入查看这段代码，你会注意到一些泛型技术中相当有趣的东西。首先泛型的类型是用这样的方法具体化的：
Dim employees As New Dictionary(Of String, Employee)
这可以翻译成“创建一个Dictionary，它的关键字是String类型，值是Employee类型”。任何时候试图储存一个不是Employee类型的对象都将导致编译错误。有必要重申，如果使用了泛型，你再用错类型得到的将是编译错误而不是运行时错误。事实上下面这段代码除非被注释掉，否则不会通过编译，就如同编译器知道Dictionary是专用于储存Employee对象，而不是String：
's = employees.Item("111-11-1111") ' This is now a syntax error
更进一步，你现在能获得全面的能感知支持。如果你输入“employees.Item(“111-11-1111”).”，将自动弹出Employee类型的成员，这说明Visual Studio知道Dictionary现在是专门储存Employee类的集合。
（未完，接《向Visual Basic程序员介绍泛型（二）》)
