先说明一下，有的代码行比较长所以不容易看清。建议先粘贴到VS.net中，这样好看一点。
这里标题中的“简单”，并不是说代码简单，而是说思路比较简单。VS.net中的PictureBox有个缺点就是不好控制位置和大小。所以MyPictureBox就是这样一种Picturebox：它有一个属性ViewMode，表示显示图片的模式，包括FitSize，TrueSize和StretchImage。后两者看名字也看得出意思来，FitSize则是一个折中的方式：当图片大小小于MyPictureBox大小的时候，不进行图片缩放。还有，MyPictureBox自动将图片放到中间，当其大小改变的时候也能保持图片在MyPictureBox的中间。另外，当图片大小大于MyPictureBox大小的时候，用户能够像Photoshop的手形工具那样“拖动”图片以方便浏览。总之，我们的MyPictureBox就这三大特点。
首先，以“Windows控件库”建立一个新工程，将一个PictureBox拖到用户控件上。界面就OK了。
然后我们要定义ViewMode。先建立一个enum:
Public Enum VMode
FitSize = 0
StretchImage = 1
TrueSize = 2
End Enum
然后建立一个变量存放ViewMode属性：
Private vViewMode As VMode = VMode.TrueSize
当ViewMode变化的时候，控件有必要向外界发出一个事件：
Public Event ViewModeChanged(ByVal Mode As VMode)
现在可以写ViewMode属性了：
Public Property ViewMode() As VMode
Get
Return vViewMode
End Get
Set(ByVal Value As VMode)
Dim changed As Boolean = False
If Value <> vViewMode Then changed = True
vViewMode = Value
If changed Then ShowPic()
RaiseEvent ViewModeChanged(Value)
End Set
End Property
这里，ShowPic()是尚未定义的方法，作用就是显示图片。
另外，既然是MyPictureBox，那就要有PictureBox的样。所以要加上一个Image属性：
Public Property Image() As Image
Get
Return PictureBox1.Image
End Get
Set(ByVal Value As Image)
If Value Is Nothing Then '判断一下Value是不是空值。
PictureBox1.BorderStyle = BorderStyle.None
Exit Property
Else
PictureBox1.BorderStyle = BorderStyle.FixedSingle
End If
Value = New Bitmap(Value)
PictureBox1.SizeMode = PictureBoxSizeMode.StretchImage
PictureBox1.Image = Value
ImageRate = Value.Width / Value.Height
ShowPic()
End Set
End Property
这里ImageRate是为了避免重复计算的开销的定义的一个变量，用来存储图像的宽高比，类型是Single。可以在前面加上它的定义。
现在我们来写ShowPic。为了代码结构分明，ShowPic内容很简单：
Private Sub ShowPic()
If PictureBox1.Image Is Nothing Then Exit Sub
If PictureBox1.Visible = False Then PictureBox1.Visible = True
ResizeImage()
End Sub
之所以要把ResizeImage单独写开来是因为这部分还有其他地方要重用。ResizeImage的作用是根据当前的ViewMode值，来改变PictureBox1的SizeMode属性，并决定是否对图片进行缩放：
Private Sub ResizeImage()
If PictureBox1.Image Is Nothing Then Exit Sub
If vViewMode = VMode.FitSize Then
If PictureBox1.Image.Width > Me.Width Or PictureBox1.Image.Height > Me.Height Then
StretchImage()
Else
If Not PictureBox1.SizeMode = PictureBoxSizeMode.AutoSize Then PictureBox1.SizeMode = PictureBoxSizeMode.AutoSize
End If
ElseIf vViewMode = VMode.StretchImage Then
StretchImage()
Else
If Not PictureBox1.SizeMode = PictureBoxSizeMode.AutoSize Then PictureBox1.SizeMode = PictureBoxSizeMode.AutoSize
End If
LocateImage()
End Sub
这一段判断有些复杂，其实应该可以写得更好一点的。StretchImage和LocateImage的作用从名字上大概就能看出来了。先看看StretchImage。它是真正缩放图片的方法。其实也不复杂：
Private Sub StretchImage()
PictureBox1.SizeMode = PictureBoxSizeMode.StretchImage
If MeRate < ImageRate Then
PictureBox1.Width = Me.Width
PictureBox1.Height = PictureBox1.Width / ImageRate
Else
PictureBox1.Height = Me.Height
PictureBox1.Width = PictureBox1.Height * ImageRate
End If
End Sub
这里MeRate用来保存MyPictureBox本身的宽高比。类型是Single，现在可以在前面加上它的定义。显然，StrechImage实际上就是改变PictureBox1的宽高。计算好图片框的大小之后，要保持图片在中间，需要计算图片框的位置。LocateImage就是作这个用的：
Private Sub LocateImage()
If PictureBox1.Width < Me.Width Then
PictureBox1.Left = (Me.Width - PictureBox1.Width) / 2
Else
PictureBox1.Left = 0
End If
If PictureBox1.Height < Me.Height Then
PictureBox1.Top = (Me.Height - PictureBox1.Height) / 2
Else
PictureBox1.Top = 0
End If
End Sub
当MyPictureBox大小改变的时候，图片的大小和位置就要重新计算。没错，应该写在Resize事件里面。不过且慢。如果不加控制的话，在用户拖动改变MyPictureBox大小的过程中，因为不停的计算图片的大小和位置，CPU的占用率会达到100%。这是很不友好的，甚至可以用“霸道”来形容。也许我们应该开一个线程，在线程当中用Sleep来避免这种情况。但是这写起来又太复杂了点。所以我们用Timer这种折中的办法。回到设计器视图，拖过来一个Timer。设置Interval值为25。在Timer1_Tick当中写上：
Private Sub Timer1_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Timer1.Tick
If vViewMode = VMode.StretchImage Or vViewMode = VMode.FitSize Then
ResizeImage()
Else
LocateImage()
End If
Timer1.Stop()
End Sub
然后再在Resize事件中写上：
Private Sub MyPictureBox_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles MyBase.Resize
MeRate = Me.Width / Me.Height
Timer1.Start()
End Sub
这样的组合就能达到目标了。
然后我们再写“拖动”图片的功能。显然，这个功能只有当ViewMode=TrueSize的时候才有用。这个功能分三部分，首先是MouseDown事件：
Private Sub PictureBox1_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBox1.MouseDown
If e.Button <> MouseButtons.Left Or ViewMode <> VMode.TrueSize Then Exit Sub
Moving = True
Me.Cursor = System.Windows.Forms.Cursors.Hand
MousePos = Me.MousePosition
OldScroll = Me.AutoScrollPosition
End Sub
这里Moving变量用来表示用户是否正在拖动图片，类型是Boolean。没定义？到前面去定义一下不就行了。还有什么MousePos，OldScroll，它们俩的类型是Point。快去定义一下。当用用户按下鼠标左键的时候，记录下鼠标位置和图片当的前滚动位置。
然后是MouseMove事件：
等等。在用户移动鼠标的时候，又要不停的计算图片框的滚动位置。为了避免再次“霸道”起来，我们又要拖进来一个Timer。设置Interval值为1。这个Timer是这样的：
Private Sub Timer2_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Timer2.Tick
MousePosNow = Me.MousePosition
Dim DeltaPos As Point = New Point((MousePos.X - MousePosNow.X), (MousePos.Y - MousePosNow.Y))
Me.AutoScrollPosition = New Point(-OldScroll.X + DeltaPos.X, -OldScroll.Y + DeltaPos.Y)
Timer2.Stop()
End Sub
就四句话，应该不太难看懂吧。
所以MouseMove就这样：
Private Sub PictureBox1_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBox1.MouseMove
If Moving Then
Timer2.Start()
End If
End Sub
第三部分就是MouseUp事件了，就两句话：
Private Sub PictureBox1_MouseUp(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBox1.MouseUp
Moving = False
Me.Cursor = System.Windows.Forms.Cursors.Default
End Sub
这样，MyPictureBox就写好了。
……没错，是写好了。运行一下看看。
不能运行？废话。我叫你再建一个WinForm程序，把MyPictureBox拖进去看看！
