第四篇：Flash游戏开发系列一：游戏中的敌人。
五、跟踪导弹
看看这个例子，在动画屏幕上按下鼠标，导弹就会跟踪玩家，直到击中玩家：
对于新手来说，一下子就实现它可能不太容易，我们来一点一点的做。
（１）导弹的方向
我们先来实现导弹朝向玩家的功能，就像下面这个：（按下鼠标观看）
首先，我们注意到，敌人的导弹是要朝向玩家的，这和前面不同。前面的敌人是一个圆头圆脑的家伙，不用分辨它的方向。我们就先来看一下如何让敌人有方向感。
首先给新手讲解一下基本知识：用鼠标来触发动画。
我们先设定一个变量，布尔类型的 clickable。在初始化的时候，我们将其设置为真，即 true。
var clickable:Boolean;
init = function () {
enemy._x = 40;
enemy._y = 350;
enemy._rotation = 0;
clickable = true;
};
而当鼠标按下的时候，我们来判断 clickable 是否为真，如果为真就可以执行新的语句，并且将 clickable 设置为假，即 false。这样，如果鼠标按下一次以后，再按就不起作用了。
onMouseDown = function () {
if (clickable) {
setInterval(run, 10);
clickable = false;
}
};
这样我们就可以进入我们的主要内容了：改变导弹的角度。
敌人到玩家之间一般情况下是会有一个夹角的。Flash 给我们提供了 Math.atan2(y,x) 来求得上图中所表示的 angle! 。所以我们很容易的就能够得到这个值 Math.atan2(dy, dx)*180/Math.PI，因为取到的是弧度，所以后面加了 *180/Math.PI 来转换成角度。
得到 angle! 以后，我们会发现，我们的导弹在 enemy._rotation = 0 的时候，已经处在上图 90 度的位置上，在 enemy._rotation = 90 的时候，已经处在上图 -180(也是0) 度的位置上，在 enemy._rotation = 180 的时候，已经处在上图 -90 度的位置上。所以我们要做一下处理，给它减去 270 度，为了让这个角度很好的保持在 0 到 360 度之间，我们再给它加上 720 度然后针对 360 度取模，最后就变成这个样子：
(Math.atan2(dy, dx)*180/Math.PI+450)%360
这样，我们计算之后得到的角度就可以直接应用到我们的 enemy 上面了。
出于习惯，我把计算角度这部分做了一个函数，所以在主运行函数 run 里面，程序看起来很简单。
剩下的不用多解释了，下面是完整的第一帧源代码：
var clickable:Boolean;
//
init = function () {
enemy._x = 40;
enemy._y = 350;
enemy._rotation = 0;
clickable = true;
};
onMouseMove = function () {
player._x = _xmouse-10;
player._y = _ymouse-10;
updateAfterEvent();
};
onMouseDown = function () {
if (clickable) {
setInterval(run, 10);
clickable = false;
}
};
getAngle = function ():Number {
var dx:Number = player._x-enemy._x;
var dy:Number = player._y-enemy._y;
return ((Math.atan2(dy, dx)*180/Math.PI+450)%360);
};
run = function () {
var angle:Number = getAngle();
enemy._rotation = angle;
};
// Run Program
init();
