Visual Basic如何传递字符串到动态链接库
现在让我们来面对这个奇怪的问题：Visual Basic如何向外部的动态链接库传递BSTR类型的字符串。
我们已经知道，Visual Basic内部使用Unicode编码，也就是说，BSTR字符串使用Unicode格式。Windows NT了使用Unicode编码，但是，Windows 9x却不支持Unicode（除非某些特例）。让我们来看一下一个BSTR变量传递到一个外部的动态链接库（Win32 API或其它）所经过的过程。
为了兼容Windows 95，Visual Basic总是（甚至在Windows NT下）创建一个ANSI BSTR字符串，将BSTR字符串的Unicode格式的字符数组转换为ANSI格式，将转换完成的字符保存在这个ANSI BSTR字符串中。Visual Basic接下来就把这个ANSI BSTR字符串传递给一个外部的函数。它甚至在需要传送Unicode字符串的Windows NT中也这么做。
传送BSTR字符串之前的准备
在传递一个BSTR字符串到一个外部的动态链接库之前，Visual Basic在其它的内存地址中创建一个新的ANSI BSTR字符串。然后再把ANSI BSTR字符串传递给动态链接库。这种复制并转移的过程如图6-6所示。
Figure 6-6. Translating a BSTR to an ABSTR
当我们第一次介绍函数CopyMemory时，我们使用它来演示Unicode到ANSI的转化过程。现在让我们用另一种方式来重新演示这个过程。（译者注：接下来的程序调用了《Win32 API Programming with Visual Basic》所附的光盘中的动态链接库rpiAPI.dll的一个函数rpiBSTRtoByteArray，由于本人没有该光盘，所以大家无法演示，敬请原谅。在此，我们虽然不能运行该函数，但仅仅拿它来了解作者的程序思想，却未为不可。）rpiAPI.dll类库中有一个函数rpiBSTRtoByteArray，它的作用是返回一个传递到这个函数的字符串的地址值VarPtr和指向值StrPtr。该函数的定义如下：
Public Declare Function rpiBSTRtoByteArray Lib "???\rpiAPI.dll" (ByRef pBSTR As String,ByRef bArray As Byte,pVarPtr As Long,pStrPtr As Long) As Long
第一个参数pBSTR为一个BSTR类型的字符串，并按引用接收。因此，传送的是BSTR的地址，而不是字符串数组的首地址。（也就是说，我们传送了一个字符串的二级指针）
第二个参数是一个缓冲区，用来存放Visual Basic传递过来的ANSI BSTR字符串的首字符内存地址（注意是按引用传递，所以传递的应该是地址。）。
最后的两个参数也是缓冲区。函数在pVarPtr变量存放的是BSTR字符串指针的地址，pStrPtr存放的是BSTR字符串的首地址。
函数返回的是字符串的字符数。最后，函数会将传递给它的字符串的首字母改为字符“x”，这样，通过查看字符串的首字母我们便可以知道动态链接库接收的是哪一个字符串。
以下是演示代码：
Sub BSTRTest()
Dim i As Integer
Dim sString As String
Dim bBuf(1 To 10) As Byte
Dim pVarPtr As Long
Dim pStrPtr As Long
Dim bTarget As Byte
Dim lTarget As Long
sString = "help"
Debug.Print "VarPtr:" & VarPtr(sString) ' 输出BSTR的地址和指向的字符串的地址
Debug.Print "StrPtr:" & StrPtr(sString)
Debug.Print "Function called. Return value:" & rpiBSTRToByteArray(sString, bBuf(1), pVarPtr, pStrPtr)
Debug.Print "Address of temp ABSTR as DLL sees it: " & pVarPtr ‘输出实际传递到外部动态链接库的ANSI BSTR的地址和字符串地址
Debug.Print "Contents of temp ABSTR as DLL sees it: " & pStrPtr
Debug.Print "Temp character array: " ‘输出临时建立的传送到外部动态链接库的ANSI BSTR字符串
For i = 1 To 10
Debug.Print bBuf(i)
Next
Debug.Print
VBGetTarget lTarget, pVarPtr, 4 ‘函数返回后检查ANSI BSTR字符串原先的地址并将其内容输出
Debug.Print "Contents of temp ABSTR after DLL returns: " & lTarget
Debug.Print "BSTR is now: " & sString‘函数返回后输出原BSTR字符串
End Sub
输出结果为：
VarPtr:1242736
StrPtr:2307556
Function called. Return value:4
Address of temp ABSTR as DLL sees it: 1242688
Contents of temp ABSTR as DLL sees it: 1850860
Temp character array: 104 101 108 112 0 0 0 0 0 0
Contents of temp ABSTR after DLL returns: 0
BSTR is now: Xelp
这几段代码首先输出的是Visual Basic中的BSTR字符串指针的地址和字符串首字符的地址。接下来调用动态链接库的函数。
在动态链接库返回后，我们试图输出ANSI BSTR字符串，但得到的结果为0。这说明这种字符串是临时创建的，函数返回后就已经被删除掉了。
最后，大家要知道，我这段代码是在Windows NT下运行的。这说明，这种字符串转换在支持Unicode的Windows NT下也发生了！真是莫名其妙！
返回的BSTR字符串
对BSTR字符串来说，传送到一个DLL函数并被返回是一个复杂的过程。
图6－7显示了这整个过程。在ABSTR字符串传递到DLL函数后，转换过程就反过来了。原来的BSTR变量str会指向一个API函数产生的Unicode字符数组。注意，这个Unicode字符数组在内存中的位置可能与原来的地址不同了。所以，我们应该依据数组的地址而不是值去判断。
Figure 6-7. The return translation
调用哪一类函数？
Windows 9x并不支持Unicode 入口的API函数，所以，基于兼容性的考虑，你必须在应用程序中调用ANSI入口的API函数。举个例子，如果你想调用SendMessage函数，你应该选择SendMessageA，而不是SendMessageW。
字符串传递的步骤
现在让我们来看一下一个BSTR字符串传递到一个外部的动态链接库所经过的步骤。
假定我们呼叫一个接收字符串参数并将它修改后返回的动态链接库函数。例如，CharUpper是个很合适的例子。这个函数将每个字符转换为大写。ANSI版本的Visual Basic声明如下：
Declare Function CharUpperA Lib "user32" ( ByVal lpsz As String ) As Long
在Windows 9x下
在Windows 9x下，字符串参数发生以下变化。记住被传递的是字符串指针，而不是实际的字符串。
首先BSTR字符串被Visual Basic复制为一个ABSTR，然后这个复制品被传送到函数CharUpperA，而CharUpperA将它作为LPSTR接收。CharUpperA处理好这个LPSTR后将结果传回Visual Basic。Visual Basic再把LPSTR转变为一个BSTR字符串。
在Windows NT下
在Windows NT下，被传递过去的字符串会经历以下的变化：
BSTR字符串被Visual Basic复制为ABSTR，并且传递到函数CharUpperA，该函数以LPSTR类型接收它。CharUpperA又把LPSTR翻译为LPWSTR，然后把这个LPWSTR传送到Unicode入口的CharUpperW。CharUpperW处理了LPWSTR后再把它返回给CharUpperA。CharUpperA将这个LPWSTR翻译为LPSTR并把它传递给Visual Basic，而Visual Basic会认为它接收的是一个ABSTR。最后Visual Basic把ABSTR转变为BSTR。
一个Unicode入口的例子
在Windows NT下，我们如果直接调用Unicode入口的函数看看会得到什么样的结果。
以下是一个ANSI版本的调用CharUpperA的例子：
s = "d:\temp"
Debug.Print s
CharUpperA s
Debug.Print s
不管是在Windows 9x还是在Windows NT下，输出结果都是这样：
d:\temp
D:\TEMP
在Windows NT下，我们尝试一下调用Unicode版本的CharUpperW：
s = "d:\temp"
Debug.Print s
CharUpperW s
Debug.Print s
但是输出结果却为：
d:\temp
d:\temp
很显然，什么地方出错了。顺便提一句，MSDN的Visual Basic文档中是这样解释CharUpper函数的返回值的：“本函数不能提示是否被成功执行。通常很少出错。所以并没有什么外部的提示。请不要在出错后调用GetLastError。“
即使如此，我们还是知道错误一定与Visual Basic将BSTR改为ABSTR有关。所以，我们再试一试以下的代码：
s = "d:\temp"
Debug.Print s
s = StrConv(s, vbUnicode)
Debug.Print s
CharUpperW s
Debug.Print s
s = StrConv(s, vbFromUnicode)
Debug.Print s
输出为：
d:\temp
d : \ t e m p
D : \ T E M P
D:\TEMP
这段代码比上一段多做的只是模拟了BSTR到ABSTR的转换。事实上，StrConv函数只是简单地接收每一个字符，然后把它们转换为Unicode格式。它不会去关心传递过来的字符串是否已经为Unicode格式了。
思考一下，第一个字符d的Unicode代码是00 64（十六进制），而在内存保存为64 00。StrConv将每一个字符转换为Unicode格式，结果就是00 64 00 00（在内存中则为64 00 00 00）。效果与在原来的每个Unicode字符后再加一个Unicode的空字节一样。
在将这个膨胀了的Unicode字符串传递到CharUpperW之前，Visual Basic欲把它转换为ANSI，于是它就变回原来的Unicode格式。于是CharUpperW就理解了传递进来的Unicode字符串，成功地将它改为大写。当转换为大写的Unicode字符串从CharUpperW返回的时候，Visual Basic又欲将它转换为Unicode，于是它又变为那种膨胀了的“Unicode“字符串。
字符串和Byte数组
Byte数组理所当然地就是成员是Byte类型的数组，例如：
Dim b(1 to 100) As Byte
我们可以使用VarPtr函数得到这个Byte类型的数组指针。
Dim lpsz As Long
lpsz = VarPtr(b(1))
数组第一个成员的地址就是数组的地址。
记得我们说过一个LPSTR就是一个指向空字节结尾的字符数组。现在我们把数组全部赋值为空：
For i = 1 To 100
b(i) = 0
Next
（虽然Visual Basic也会自动帮你初始化，但是老是依赖它的这种初始化功能却不是一个良好的编程习惯。）
在Byte数组和BSTR字符串间相互转化
要将一个BSTR字符串转化为Byte数组，我们有两种不同的方法。Visual Basic风格的方法如下：
Dim s As String
s = "help"
Dim b(1 To 8) As Byte
For i = 1 To 8
b(i) = AscB(MidB(s, i))
Next
另一种C++风格的方法可以是：
s = "help"
Dim b(1 To 8) As Byte
CopyMemory b(1), ByVal StrPtr(s), LenB(s)
不管是哪种方法，我们都得到：
104 0 101 0 108 0 112 0
从上可见，在每一个Unicode格式的字符串中，每个字符都是颠倒保存的。
另一方面，如果想把一个Byte数组转化为一个BSTR字符串，Visual Basic提供了几个函数帮助我们做到这一点。如果b是一个Unicode格式的Byte数组，那么我们就可以直接在代码中这样写：
Dim t As String
t = b
而如果是ANSI格式的Byte数组就这样写：
Dim t As String
t = StrConv(b, vbUnicode)
在BSTR和LPTSTR间进行转换
现在让我们来看一下如何在BSTR和LPTSTR间进行转换。
从BSTR到LPWSTR
将一个BSTR字符串转换为仿Unicode的Byte数组在理论上是很容易的。因为BSTR所指向的字符数组本来就是Unicode格式的。我们只要把字符一个个拷贝过去就行了。以下是一个将BSTR转换为LPWSTR的函数：
Function BSTRtoLPWSTR(sBSTR As String, b() As Byte, lpwsz As Long) As Long
' Input: a nonempty BSTR string
' Input: **undimensioned** byte array b()
' Output: Fills byte array b() with Unicode char string from sBSTR
' Output: Fills lpwsz with a pointer to b() array
' Returns byte count, not including terminating 2-byte Unicode null character
' Original BSTR is not affected
Dim cBytes As Long
cBytes = LenB(sBSTR)
' ReDim array, with space for terminating null
ReDim b(1 To cBytes + 2) As Byte
' Point to BSTR char array
lpwsz = StrPtr(sBSTR)
' Copy the array
CopyMemory b(1), ByVal lpwsz, cBytes + 2
' Point lpsz to new array
lpwsz = VarPtr(b(1))
' Return byte count
BSTRtoLPWSTR = cBytes
End Function
函数接收一个BSTR和一个动态Byte数组，以及一个长整型变量并将BSTR转换为一个LPWSTR，保存在Byte数组中。数组的首地址赋予lpwsz。它的返回值是数组的长度。下面是一个调用该函数的例子。
Dim b() As Byte
Dim lpsz As Long, lng As Long
lng = BSTRToLPWSTR("here", b, lpsz)
如果你仔细看了BSTR和C语言类型的LPSTR和LPWSTR这几个部分的话，你会发现，其实上面三句代码与下面代码等价。
lpsz = StrPtr(sBSTR)
从BSTR到LPSTR
将BSTR转换到LPSTR与LPWSTR类似，只须注意Unicode格式到ANSI格式的转换就行了。函数如下：
Function BSTRtoLPSTR(sBSTR As String, b() As Byte, lpsz As Long) As Long
' Input: a nonempty BSTR string
' Input: **undimensioned** byte array b()
' Output: Fills byte array b() with ANSI char string
' Output: Fills lpsz with a pointer to b() array
' Returns byte count, not including terminating null
' Original BSTR is not affected
Dim cBytes As Long
Dim sABSTR As String
cBytes = LenB(sBSTR)
' ReDim array, with space for terminating null
ReDim b(1 To cBytes + 2) As Byte
' Convert to ANSI
sABSTR = StrConv(sBSTR, vbFromUnicode)
' Point to BSTR char array
lpsz = StrPtr(sABSTR)
' Copy the array
CopyMemory b(1), ByVal lpsz, cBytes + 2
' Point lpsz to new array
lpsz = VarPtr(b(1))
' Return byte count
BSTRtoLPSTR = cBytes
End Function
从LPWSTR到BSTR
如果从一个API函数返回是LPWSTR（就是说一个指向空字节结尾的Unicode格式的字符串指针），Visual Basic可以轻松地将它转换为BSTR。
以下是一个小小的工具函数：
Function LPWSTRtoBSTR(ByVal lpwsz As Long) As String
' Input: a valid LPWSTR pointer lpwsz
' Return: a sBSTR with the same character array
Dim cChars As Long
' Get number of characters in lpwsz
cChars = lstrlenW(lpwsz)’该函数为strlen的C语言版本
' Initialize string
LPWSTRtoBSTR = String$(cChars, 0)
' Copy string
CopyMemory ByVal StrPtr(LPWSTRtoBSTR), ByVal lpwsz, cChars * 2
End Function
从LPSTR到BSTR
将上面的小函数做一个小小的修改，我们就可以得到一个将LPSTR转换为BSTR的函数。（注意Trim函数的功能是去除前导空白和尾随空白）
Function LPSTRtoBSTR(ByVal lpsz As Long) As String
' Input: a valid LPSTR pointer lpsz
' Output: a sBSTR with the same character array
Dim cChars As Long
' Get number of characters in lpsz
cChars = lstrlenA(lpsz)
' Initialize string
LPSTRtoBSTR = String$(cChars, 0)
' Copy string
CopyMemory ByVal StrPtr(LPSTRtoBSTR), ByVal lpsz, cChars
' Convert to Unicode
LPSTRtoBSTR = Trim0(StrConv(LPSTRtoBSTR, vbUnicode))
End Function
