VB外接程序的制做
二,在VB中创建您自己工具条和菜单
创建工具条依然需要使用到VBI,只要和VB打交道,必须有它,同时在上篇文章所阐述的菜单项的制做方法是对你现在即将做的工作有用的.有一点你必须知道,无论是创建按钮,还是创建菜单项,他们之间是没有区别的.只是有一些地方有一点点不同而已.
怎样创建工具条呢?非常简单.
VBI.CommandBars.Add cbsToolsBarName
此方法后面当然有其它可选参数,但是有些东西对于现在我要阐述的问题是无关的.
Function Add([Name], [Position], [MenuBar], [Temporary]) As CommandBar
[Position] 是位置.是浮动在VB中还是在VB的上边,下边,左边,右边?参数,你待参考 MsoBarPosition.至于 [MenuBar]参数,指定是哪个菜单栏啦,这个就自己去摸索吧.当然,最后一个参数,我也不知道它有什么用,单至少不会影响你当前的工作,而且以后也不会的.
VBI.CommandBars.Add cbsToolsBarName中的cbsToolsBarName当然是我们的工具条名称.你最好用常量方式.每次向它加按钮时,将会节约你写汉字的事件,如果你写英文,当用户在工具栏点右键时出现的菜单里写的工具条名称是英文的.如果你写中文的话,就是中文的.在处理工具条上我不是高手,因为目前为止,我还不能向菜单条添加一个和[文件]菜单这样的菜单,只能添加它的子项.曾经有一次试图添加,但是可能由于不恰当,造成又一次的失败.如果你知道了一定别忘了告诉我!
在添加了一个工具栏后,向工具条里添加按钮是和向[工具]这样的菜单中添加菜单项是一样的.只是结果是添加到你的工具条里了,同时字符串将用于按钮的ToolTipText而已,这里,你必须为每个按钮准备个图标,一般是32*32的.其它大小当然也可以,只是会变形而已.使用剪贴板加载图标,然后使用上篇文章中所说的PasteFace粘贴就可以了.无论何中格式,均可以添加到按钮上.只要是VB支持的图形.当然,VB支持GIF但是粘贴上的绝对不是动画.这个方法只是封装了BitBlt,把剪贴板中的图象放到一个 DC对象,然后BitBlt到按钮上而已.即使你加载一个GIF,按钮上只能看到的是GIF的第一帧,这何用[图画]程序打开一个GIF是一个道理.我把一段我在开发CoderHelper里用来添加按钮的代码复制出来给你也许它对你非常有用.
Public Function AddToMenu(txtCaption As String, Owner As String, ResIconID As Long, Optional Before, Optional ID As Long) As CommandBarEvents
Dim cMenu As Object
Set cMenu = AddCommandBar(txtCaption, Owner, ResIconID, Before)
'吸取事件
Set AddToMenu = VBI.Events.CommandBarEvents(cMenu)
End Function
Function AddCommandBar(sCaption As String, Owner As String, ResIconID As Long, Optional Before) As Office.CommandBarControl
Dim cbMenuCommandBar As Office.CommandBarControl '命令栏对象
Dim cbMenu As CommandBar
On Error GoTo AddToAddInCommandBarErr
'察看能否找到外接程序菜单
Set cbMenu = VBI.CommandBars(Owner)
If cbMenu Is Nothing Then
'没有有效的外接程序,过程失败
Exit Function
End If
'添加它到命令栏
Set cbMenuCommandBar = cbMenu.Controls.Add(1, , , Before)
'设置标题
cbMenuCommandBar.Caption = sCaption
Clipboard.Clear
Clipboard.SetData LoadResPicture(ResIconID, vbResBitmap)
'为此按钮设置图标
cbMenuCommandBar.PasteFace
Clipboard.Clear
Set AddCommandBar = cbMenuCommandBar
Exit Function
AddToAddInCommandBarErr:
End Function
在 OnConnection 我是这样使用的.
先 VBI.CommandBars.Add MyName 'MyName是工具条的名称常量,Public Const MyName = "程序员助手工具条" Public Const MyFunName = "程序员助手快捷命令" '这两个常量是在模块modMain中定义的.所以在整个CoderHelper中都可用.因此方便了你在任何一个子程序中添加按钮.虽然我不哪么对,原因非常实在,那样你就是非常愚蠢的,乱乱的代码会让你发疯,所以最好不要哪样做.VBI.CommandBars.Add MyName 完了后你可以象我下面的代码这么做
Set cbeVBExport = AddToMenu("Share Dll编译向导", MyName, 109)
Set PjtExplorer = AddToMenu("工程类浏览器", MyName, 113)
Set ucFileEditor = AddToMenu("文件编辑器", MyName, 112)
Set weCmdLine = AddToMenu("命令行", MyName, 111)
109,112,113,111 是资源代码,在AddCommandBar中,LoadResPicture(ResIconID, vbResBitmap)的语句是针对位图资源的.而这些数字就是位ResIconID准备的.给你的代码省去了你很多事情,你要做的只是给按钮声明个事件名称,找个图片,找个字符串,然后把图片加载到资源文件中,然后 Set 事件名称= AddToMenu ("字符串",工具条名称,图片资源代码)
然后在 象我在CoderHelper 中一样 :
Private Sub cbeVBExport_Click(ByVal CommandBarControl As Object, handled As Boolean, CancelDefault As Boolean)
DoCommand "vbexport", ""
End Sub
就可以了.其中的三个参数很明显.这个现在不是我要为你所阐述的.这个目前的工作无关.不用去操心.干吗非操心与正题无关的呢!
也许你可以看到,我的CoderHelper 中的 命令行 负责了很多任务.你猜对了.为了运行可靠,何编程的需要.这种方式是相当不错的.只要在 DoCommand 中处理好错误.其它地方就不用操心了!不用到处都是 On Error ....等代码.
第一个按钮添加完了.添第二个是同样的方法.
菜单是同样的道理.向菜单里添加些项.同样是这种方法.是没有任何区别的.到了这里你有可能发现,外接程序调用了Office 的运行库 mso.dll.包括目前所有微软的大软件,几乎都在使用它,这就是为什么有时候 Office 做了安装更改后启动VB时会无聊的运行 Office 的安装程序.
