分享
 
 
 

VB实现SQL Server数据库备份/恢复

王朝mssql·作者佚名  2006-12-16
窄屏简体版  字體: |||超大  

'*************************************************************************

'**模 块 名:fBackupDatabase_a

'**描 述:备份数据库,返回出错信息,正常恢复,返回""

'**调 用:fBackupDatabase_a "备份文件名","数据库名"

'**参数说明:

'** sBackUpfileName 恢复后的数据库存放目录

'** sDataBaseName 备份的数据名

'** sIsAddBackup 是否追加到备份文件中

'**说 明:引用Microsoft ActiveX Data Objects 2.x Library

'**创 建 人:邹建

'**日 期:2003年12月09日

'*************************************************************************

Public Function fBackupDatabase_a(ByVal sBackUpfileName$ _

, ByVal sDataBaseName$ _

, Optional ByVal sIsAddBackup As Boolean = False _

) As String

Dim iDb As ADODB.Connection

Dim iConcStr$, iSql$, iReturn$

On Error GoTo lbErr

'创建对象

Set iDb = New ADODB.Connection

'连接数据库服务器,根据你的情况修改连接字符串

iConcStr = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Data Source=zj"

iDb.Open iConcStr

'生成数据库备份语句

iSql = "backup database [" & sDataBaseName & "]" & vbCrLf & _

"to disk='" & sBackUpfileName & "'" & vbCrLf & _

"with description='" & "zj-backup at:" & Date & "(" & Time & ")'" & vbCrLf & _

IIf(sIsAddBackup, "", ",init")

iDb.Execute iSql

GoTo lbExit

lbErr:

iReturn = Error

lbExit:

fBackupDatabase_a = iReturn

End Function

'*************************************************************************

'**模 块 名:frestoredatabase_a

'**描 述:恢复数据库,返回出错信息,正常恢复,返回""

'**调 用:frestoredatabase_a "备份文件名","数据库名"

'**参数说明:

'** sDataBasePath 恢复后的数据库存放目录

'** sBackupNumber 是从那个备份号恢复

'** sReplaceExist 指定是否覆盖已经存在的数据

'**说 明:引用Microsoft ActiveX Data Objects 2.x Library

'**创 建 人:邹建

'**日 期:2003年12月09日

'*************************************************************************

Public Function fRestoreDatabase_a(ByVal sBackUpfileName$ _

, ByVal sDataBaseName$ _

, Optional ByVal sDataBasePath$ = "" _

, Optional ByVal sBackupNumber& = 1 _

, Optional ByVal sReplaceExist As Boolean = False _

) As String

Dim iDb As ADODB.Connection, iRe As ADODB.Recordset

Dim iConcStr$, iSql$, iReturn$, iI&

On Error GoTo lbErr

'创建对象

Set iDb = New ADODB.Connection

Set iRe = New ADODB.Recordset

'连接数据库服务器,根据你的情况修改连接字符串

iConcStr = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Data Source=zj"

iDb.Open iConcStr

'得到还原后的数据库存放目录,如果没有指定,存放到SQL SERVER的DATA目录

If sDataBasePath = "" Then

iSql = "select filename from master..sysfiles"

iRe.Open iSql, iDb, adOpenKeyset, adLockReadOnly

iSql = iRe(0)

iRe.Close

sDataBasePath = Left(iSql, InStrRev(iSql, "\"))

End If

'检查数据库是否存在

If sReplaceExist = False Then

iSql = "select 1 from master..sysdatabases where name='" & sDataBaseName & "'"

iRe.Open iSql, iDb, adOpenKeyset, adLockReadOnly

If iRe.EOF = False Then

iReturn = "数据库已经存在!"

iRe.Close

GoTo lbExit

End If

iRe.Close

End If

'关闭用户进程,防止其它用户正在使用数据库,导致数据恢复失败

iSql = "select spid from master..sysprocesses where dbid=db_id('" & sDataBaseName & "')"

iRe.Open iSql, iDb, adOpenKeyset, adLockReadOnly

While iRe.EOF = False

iSql = "kill " & iRe(0)

iDb.Execute iSql

iRe.MoveNext

Wend

iRe.Close

'获取数据库恢复信息

iSql = "restore filelistonly from disk='" & sBackUpfileName & "'" & vbCrLf & _

"with file=" & sBackupNumber

iRe.Open iSql, iDb, adOpenKeyset, adLockReadOnly

'生成数据库恢复语句

iSql = "restore database [" & sDataBaseName & "]" & vbCrLf & _

"from disk='" & sBackUpfileName & "'" & vbCrLf & _

"with file=" & sBackupNumber & vbCrLf

With iRe

While Not .EOF

iReturn = iRe("PhysicalName")

iI = InStrRev(iReturn, ".")

iReturn = IIf(iI = 0, "", Mid(iReturn, iI)) & "'"

iSql = iSql & ",move '" & iRe("LogicalName") & _

"' to '" & sDataBasePath & sDataBaseName & iReturn & vbCrLf

.MoveNext

Wend

.Close

End With

iSql = iSql & IIf(sReplaceExist, ",replace", "")

iDb.Execute iSql

iReturn = ""

GoTo lbExit

lbErr:

iReturn = Error

lbExit:

fRestoreDatabase_a = iReturn

End Function

 
 
 
免责声明:本文为网络用户发布,其观点仅代表作者个人观点,与本站无关,本站仅提供信息存储服务。文中陈述内容未经本站证实,其真实性、完整性、及时性本站不作任何保证或承诺,请读者仅作参考,并请自行核实相关内容。
2023年上半年GDP全球前十五强
 百态   2023-10-24
美众议院议长启动对拜登的弹劾调查
 百态   2023-09-13
上海、济南、武汉等多地出现不明坠落物
 探索   2023-09-06
印度或要将国名改为“巴拉特”
 百态   2023-09-06
男子为女友送行,买票不登机被捕
 百态   2023-08-20
手机地震预警功能怎么开?
 干货   2023-08-06
女子4年卖2套房花700多万做美容:不但没变美脸,面部还出现变形
 百态   2023-08-04
住户一楼被水淹 还冲来8头猪
 百态   2023-07-31
女子体内爬出大量瓜子状活虫
 百态   2023-07-25
地球连续35年收到神秘规律性信号,网友:不要回答!
 探索   2023-07-21
全球镓价格本周大涨27%
 探索   2023-07-09
钱都流向了那些不缺钱的人,苦都留给了能吃苦的人
 探索   2023-07-02
倩女手游刀客魅者强控制(强混乱强眩晕强睡眠)和对应控制抗性的关系
 百态   2020-08-20
美国5月9日最新疫情:美国确诊人数突破131万
 百态   2020-05-09
荷兰政府宣布将集体辞职
 干货   2020-04-30
倩女幽魂手游师徒任务情义春秋猜成语答案逍遥观:鹏程万里
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案神机营:射石饮羽
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案昆仑山:拔刀相助
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案天工阁:鬼斧神工
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案丝路古道:单枪匹马
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案镇郊荒野:与虎谋皮
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案镇郊荒野:李代桃僵
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案镇郊荒野:指鹿为马
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案金陵:小鸟依人
 干货   2019-11-12
倩女幽魂手游师徒任务情义春秋猜成语答案金陵:千金买邻
 干货   2019-11-12
 
推荐阅读
 
 
 
>>返回首頁<<
 
靜靜地坐在廢墟上,四周的荒凉一望無際,忽然覺得,淒涼也很美
© 2005- 王朝網路 版權所有