对于custom attribute这个东西，我有很长一段时间都很糊涂，后来结合il才大概有了一点点理解，在这里通过一个例子结合il代码说说我的看法，顺便和大家交流一下。
用c#写的例子如下：
using System;
01: namespace AttriTest
02: {
03: class MainTest
04: {
05: static void Main(string[] args)
06: {
07:
08: Color br=Color.red | Color.green;
09:
10: Console.WriteLine(br.ToString());
11: Console.Read();
12: }
13: }
14: [Flags]
15: enum Color
16: {
17: red=0x001,
18: blue=0x002,
19: green=0x004,
20: }
21: }
显然，使用到custom attribute的是14行[Flags]，它等价于[FlagsAttribute]，在c#中允许省略其中的Attribute后缀。首先强调一点，在这里引用的类是System.FlagsAttribute，它只不过是一个class，除了继承自System.Attribute外，和其他的类没有任何区。
[Flags]的作用大家应该很清楚，那就是把Color枚举类修饰为“位标记”。从行为上可以看出这一点，上面这段代码的运行结果是
red,green
clr知道我们的Color类是“位标记”的，所以0x005就表示既有红又有绿。如果我们去掉14行，那么运行结果为
5
说明对于一个普通的枚举来说，5是一个没有定义的值，只好返回数值了。
那么clr是怎么做到这一点的呢？从c#代码上看不出什么名堂，只好从il代码上来看了。先看Main函数的代码：
.method private hidebysig static void Main(string[] args) cil managed
{
.entrypoint
.maxstack 1
.locals init ([0] valuetype AttriTest.Color 'br')
IL_0000: ldc.i4.5
IL_0001: stloc.0
IL_0002: ldloc.0
IL_0003: box AttriTest.Color
IL_0008: call instance string [mscorlib]System.Enum::ToString()
IL_000d: call void [mscorlib]System.Console::WriteLine(string)
IL_0012: call int32 [mscorlib]System.Console::Read()
IL_0017: pop
IL_0018: ret
} // end of method MainTest::Main
从IL_0000行可以看出，编译器把枚举值当作常数来处理，所以直接把 Color.red | Color.green 的值5赋給了内部变量[0]，即br，然后装箱，并调用Enum::ToString()。这一系列操作中，[Flags]起作用的地方只在最后这个ToString().
System.Enum类定义在mscorlib.dll程序集里，ToString()的代码如下
.method public hidebysig virtual instance string
ToString() cil managed
{
.maxstack 3
.locals (class System.Type V_0,
class System.Reflection.FieldInfo V_1,
object V_2)
IL_0000: ldarg.0
IL_0001: call instance class System.Type System.Object::GetType()
IL_0006: stloc.0
IL_0007: ldloc.0
IL_0008: call class System.Reflection.FieldInfo System.Enum::GetValueField(class System.Type)
IL_000d: stloc.1
IL_000e: ldloc.1
IL_000f: castclass System.Reflection.RuntimeFieldInfo
IL_0014: ldarg.0
IL_0015: ldc.i4.0
IL_0016: callvirt instance object System.Reflection.RuntimeFieldInfo::InternalGetValue(object,
bool)
IL_001b: stloc.2
IL_001c: ldloc.0
IL_001d: ldloc.2
IL_001e: call string System.Enum::InternalFormat(class System.Type,
object)
IL_0023: ret
} // end of method Enum::ToString
通篇都没有FlagsAttribute的影子，前面的代码获取枚举类型内部的私有字段"value__"的值，最后又把操作交给了另一个函数Enum::InternalFormat(Type,object),由他来完成最后的将值转换成字符串的操作。
.method private hidebysig static string InternalFormat(class System.Type eT,
object 'value') cil managed
{
.maxstack 3
.locals (string V_0)
IL_0000: ldarg.0
IL_0001: ldtoken System.FlagsAttribute
IL_0006: call class System.Type System.Type::GetTypeFromHandle(valuetype System.RuntimeTypeHandle)
IL_000b: ldc.i4.0
IL_000c: callvirt instance bool System.Reflection.MemberInfo::IsDefined(class System.Type,
bool)
IL_0011: brtrue.s IL_0027
IL_0013: ldarg.0
IL_0014: ldarg.1
IL_0015: call string System.Enum::InternalGetValueAsString(class System.Type,
object)
IL_001a: stloc.0
IL_001b: ldloc.0
IL_001c: brtrue.s IL_0025
IL_001e: ldarg.1
IL_001f: callvirt instance string System.Object::ToString()
IL_0024: ret
IL_0025: ldloc.0
IL_0026: ret
IL_0027: ldarg.0
IL_0028: ldarg.1
IL_0029: call string System.Enum::InternalFlagsFormat(class System.Type,
object)
IL_002e: ret
} // end of method Enum::InternalFormat
IL_0000行先将参数[0]入栈，这个参数是一个System.Type对象，代表我们定义的枚举类。IL_0001行有一个叫ldtoken的il指令，关于这个指令的作用，.NET Framework SDK 文档上的解释是“将元数据标记转换为其运行时表示形式，传递的标记被转换为 RuntimeHandle 并被推送到堆栈上。”这里的RuntimeHandle是RuntimeTypeHandle，这是一个值类型，核心是一个32位的整数，所以这个指令的作用是得到一个类似于Win32中常说的句柄的东西，标识FlagsAtrribute类的元数据，下一行，IL_0006通过这个句柄获取一个标识FlagsAttribute类的Type对象。最后IL_000c行是核心，它通过调用MemberInfo::IsDefine(Type,bool)函数来检测我们定义的枚举类型有没有附带FlagsAttribute。这个函数是一个实例函数，所以一共有三个参数，第一个参数是IL_0000行入栈的，类型为System.Type(注意：System.Type继承自System.Reflection.MemberInfo)，当我们这个例子运行到这里时它指向类型AttriTest.Color,第二个参数是IL_0006行入栈的，类型也是System.Type，现在它指向FlagsAttribute，最后一个参数是bool类型的，在IL_000b行入栈，值为0 (false)，告诉IsDefine函数，不用搜索继承链。最后从IL_0011行可看出，如果我们的Color类型定义了FlagsAttribute，它将调用InternalFlagsFormat函数，否则将直接调用InternalGetValueAsString函数，到这就可以看出FlagsAttribute的作用了。
下一个问题就是IsDefined是如何实现的，即clr是怎么知道一个类是否定义了某个custom attribute。我沿着调用路线往上走，却发现MemberInfo本身的IsDefined函数是一个abstract函数，没有任何代码，而Type类也没有重写这个函数，倒是Type的每个继承类都重写了这个函数。仔细追究上面的代码，可以看出IL_000c这行虚调用(callvirt)指向的对象(前面分析过它是我们调用InternalFormat函数时传进来的第一个参数arg_0)来自于上面那个函数ToString()中的IL_0001行，也就是GetType()的返回值， 难道Type只是一个抽象类？GetType()内部生成了一个类型为Type的某个子类的对象，并返回了它？这一点我从il上看不出来(原因一会儿再说吧)，自己也想不明白，还请哪位知情人赐教，或者哪位“好事”者一起研究研究。
但是从Type的子类重写的IsDefine函数中可以看到，最后它调用函数System.Reflection.CustomAttribute::IsDefined(class System.Type, class System.Type, bool)，这完全在情理之中，我们回到了名字就叫CustomAttribute的类，由它来解决正合适。沿着它的il代码又走了几个函数，最后遇到了函数CustomAttribute::IsCADefined(class System.RuntimeType caType,native int module,int32 token)，这应该是问题的最终解，但可惜这个函数后面的method implementation后缀是cil managed internalcall,对于internalcall，msdn的解释是An internal call is a call to a method implemented within the common language runtime itself. 总之，我们看不到它是怎么实现的，所以只能追到这儿为止了。By the way, Object.GetType()内部调用的函数InternalGetType()也是一个internalcall函数，所以同样无法知道内部是怎么实现的，也只好这样了。
总结一下，最后没有什么太有用的结果，不过至少知道了如果自己要使用custom attribute的话，有这么几个函数可以使用，System.MemberInfo.IsDefined，以及他派生类重写的函数，还有System.Reflection.CustomAttribute里的一些静态函数。剩下的就是把这一天辛劳的过程贴出来，大家分享一下吧。
